属性

首先将属性-是否有检查框设置成真。(最好也将类型设置成报表列表框,不然无法显示报表列,同时选择框也不能按列放置)

代码

.版本 2
.支持库 iext

.程序集 窗口程序集_启动窗口

.子程序 __启动窗口_创建完毕
.局部变量 i, 整数型

超级列表框1.插入列 (, , , , , )
.计次循环首 (10, i)
    超级列表框1.插入表项 (, 到文本 (i), , , , )
    超级列表框1.置状态图片 (i - 1, 选择 (超级列表框1.取当前状态图片 (i - 1) = 0, 1, 0))
.计次循环尾 ()

如下图:

易语言 超级列表框 设置选中状态-选择框的 方法

运行效果:

易语言 超级列表框 设置选中状态-选择框的 方法

解释

置状态图片:

设置指定表项的状态图片。如果“是否有检查框”属性为真,调用“置状态图片 (表项索引, 0)”或“置状态图片 (表项索引, 1)”可以设置表项检查框的选中状态(前者为不选中,后者为选中)。

取当前状态图片:

取回指定表项的当前状态图片索引,图片索引指向状态图片组属性中的某一图片,从 0 开始,-1 表示无图片。如果“是否有检查框”属性为真,返回值是当前检查框的选中状态,1表示被选中,0表示未选中。

更多

判断是否表项选中:

.版本 2
.支持库 iext

.子程序 _按钮1_被单击
.局部变量 文本, 文本型
.局部变量 i, 整数型

.计次循环首 (超级列表框1.取表项数 (), i)
    .如果真 (超级列表框1.取当前状态图片 (i - 1) = 1)
        编辑框1.内容 = 编辑框1.内容 + “表项” + 到文本 (i) + “被选中” + “    ”
    .如果真结束

.计次循环尾 ()

易语言 超级列表框 设置选中状态-选择框的 方法

实际运行效果:
易语言 超级列表框 设置选中状态-选择框的 方法

添加全选取消全选功能:

在启动窗口添加一个“选择框”,并将属性-选中设置为“真”

.版本 2
.支持库 iext

.子程序 _选择框1_被单击
.局部变量 i, 整数型

.如果 (选择框1.选中 = 真)
    .计次循环首 (超级列表框1.取表项数 (), i)
        超级列表框1.置状态图片 (i - 1, 1)
    .计次循环尾 ()

.否则
    .计次循环首 (超级列表框1.取表项数 (), i)
        超级列表框1.置状态图片 (i - 1, 0)
    .计次循环尾 ()

.如果结束

易语言 超级列表框 设置选中状态-选择框的 方法

取消全选后的效果:

易语言 超级列表框 设置选中状态-选择框的 方法

其他

视频教程: https://www.eyuyan.tv/p1289